home *** CD-ROM | disk | FTP | other *** search
/ 8bitfiles.net/archives / archives.tar / archives / commodore-scene-files / Coverdisks / CDU / V3D11.D64 / techno info (.txt) < prev    next >
Encoding:
Commodore BASIC  |  2019-04-13  |  2.5 KB  |  71 lines
  1. 10 REM ********************************
  2. 20 REM *     TECHNO INFO PROGRAM      *
  3. 30 REM *  WRITTEN FOR SEPTEMBER 1990  *
  4. 40 REM *  ISSUE OF CDU BY J.R.FINCH.  *
  5. 50 REM ********************************
  6. 60 :
  7. 70 :
  8. 80 SA=832: REM ** START ADDRESS FOR DATA
  9. 100 PRINT"[147]":INPUT"HOW MANY DATA ITEMS TO CREATED (1-100)  ";N
  10. 110 IF N<1 OR N>100 THEN 100
  11. 120 PRINT"PLEASE WAIT: STORING VALUES AS IF IT    WERE SPRITE DATA INFO..."
  12. 125 PRINT"PROGRAM WILL WRITE LINES CONTAINING 8"
  13. 127 PRINT"BYTES AND THEREFORE MAY WRITE MORE THAN YOU INTEND."
  14. 130 FORX=1TON:POKE831+X,INT(RND(1)*256):NEXT: REM ** CREATE RANDOM DATA
  15. 140 :
  16. 150 INPUT"ENTER START LINE NUMBER (1000-60000)    ";SL
  17. 160 IF SL<1000 OR SL>60000 THEN PRINT"[145][145][145]":GOTO150
  18. 170 INPUT"ENTER LINE INCREMENT (1-100)            ";LI
  19. 180 IF LI<1 OR LI>100 THEN PRINT"[145][145][145][145]":GOTO170
  20. 190 :
  21. 200 REM *******************************
  22. 210 REM * WE SHALL START PRINTING THE *
  23. 220 REM * DATA, EXITING AND THEN      *
  24. 230 REM * RE-ENTERING THE PROGRAM     *
  25. 240 REM * SHORTLY: SAVE ANY VARIABLES *
  26. 250 REM * NOW TO SOME LOCATIONS IN    *
  27. 260 REM * MEMORY AS SHOWN BY THE      *
  28. 270 REM * EXAMPLE LINE 300            *
  29. 280 REM *******************************
  30. 290 :
  31. 300 POKE 679,X1:POKE 680,Y1:POKE 681,C1
  32. 310 :
  33. 320 REM *******************************
  34. 330 REM * STORE START LINE/ ADDRESS / *
  35. 340 REM * INCREMENT/ NO.OF DATA ITEMS *
  36. 350 REM *******************************
  37. 360 :
  38. 365 POKE 682,((SL/256)-INT(SL/256))*256:POKE 683,SL/256
  39. 370 POKE 685,((SA/256)-INT(SA/256))*256:POKE 686,SA/256
  40. 375 POKE 687,LI
  41. 380 POKE 688,((N/256)-INT(N/256))*256:POKE 689,N/256
  42. 385 :
  43. 390 REM *******************************
  44. 400 REM * PROGRAM WILL RETURN TO LINE *
  45. 410 REM * 500 SO START RETRIEVING     *
  46. 420 REM * VARIABLES AND CALCULATING   *
  47. 430 REM * NEXT LINE NUMBER AND ADDRESS*
  48. 440 REM * AT THAT LINE AND LET LOC'N  *
  49. 450 REM * TWO HOLD THE VALUE FOR THE  *
  50. 460 REM * NUMBER OF LINES DONE SO FAR *
  51. 470 REM *******************************
  52. 480 :
  53. 490 POKE2,0
  54. 500 NL=(PEEK(682)+PEEK(683)*256)+PEEK(687)*PEEK(2): REM ** CALC. NEXT LINE NMBR
  55. 510 AD=PEEK(685)+PEEK(686)*256+PEEK(2)*8: REM ** START ADDR. FOR 1ST OF NEXT 8
  56. 520 :
  57. 525 IF AD>=((PEEK(688)+PEEK(689)*256)+(PEEK(685)+PEEK(686)*256)) THEN 620
  58. 530 PRINT"[147]"NL"DATA";
  59. 540 FOR X=0 TO 7: PRINT PEEK(AD+X)"[157],";: NEXT: REM ** PRINT OUT VALUES OF NEXT 8
  60. 550 PRINT"[157] ":PRINT"GOTO500";:REM ** END OF LAST LINE - GET READY TO EXIT
  61. 560 :
  62. 565 POKE2,PEEK(2)+1: REM ** INCREASE NO. OF LINES DONE (MAX=255)
  63. 570 POKE631,13:POKE632,13:POKE198,2:END
  64. 580 REM ^^ FILL BUFFER WITH CHR$(13) AND EXIT PROGRAM
  65. 590 REM ** LINE WILL BE ENTERED, AND COMPUTER WILL EXECUTE 'GOTO' STATEMENT
  66. 600 REM ** THUS RETURNING TO LINE 500 FOR MORE IF ANY IS LEFT
  67. 610 :
  68. 620 REM ** ALL DONE SO EXIT PROGRAM (RETURN FROM A SUBROUTINE IF NECESSARY)
  69. 630 :
  70. 640 END
  71.